Perl og XPath:manglende poster i databasetabellen

Du har allerede en forklaring og en rettelse, men jeg foreslår følgende ændringer

• Du bør prepare INSERT INTO SQL-sætning og derefter execute det inden for løkken. do har en meget større overhead

• // ( descendant-or-self::node() ) XPath-konstruktionen er dyr, og du bør reservere den til tilfælde, hvor du ikke aner, hvor elementet vil være i dokumentet, hvilket er meget sjældent. I dette tilfælde row1 elementer er på /database/row1s/row1 og row2 elementer er ved row2s/row2 i forhold til det

• Det er meget renere at bruge forskellige afgrænsningstegn, hvis du vil bruge anførselstegn inden for en citeret streng. For eksempel "My name is \"$name\"" er meget bedre som qq{My name is "$name"}

Her er en version af dit program, der kan hjælpe.

use strict;
use warnings;

use XML::XPath;
use DBI;

my $xp = XML::XPath->new( filename => 'animals4.xml' );

my $dbh = DBI->connect(
   'DBI:mysql:test', 'user', 'pw',
   { RaiseError => 1, PrintError => 0}
) or die "Fehler beim Verbidungsaufbau zum MariaDB-Server: $DBI::err -< $DBI::errstr\n";

my $insert_animal = $dbh->prepare('INSERT INTO animal4 (name, category, type, size) VALUES (?, ?, ?, ?)');

for my $row1 ( $xp->findnodes('/database/row1s/row1') ) {

   my $name     = $row1->getAttribute('name');
   my $category = $row1->getAttribute('category');

   printf qq{Level --- row1 "name" gives: $name\n};

   my @row2 = $xp->findnodes('row2s/row2', $row1);

   if ( @row2 ) {
      for my $row2 ( @row2 ) {

         my $type = $row2->getAttribute('type');
         my $size = $row2->getAttribute('size');

         print qq{Level row2 "type" gives: $type\n};
         print qq{Level row2 "size" gives: $size\n};

         $insert_animal->execute($name, $category, $type, $size);
      }
   }
   else {
      $insert_animal->execute($name, $category, undef, undef);
   }
}

output

Level --- row1 "name" gives: fox
Level row2 "type" gives: 1
Level row2 "size" gives: 10
Level row2 "type" gives: 2
Level row2 "size" gives: 8
Level --- row1 "name" gives: horse
Level row2 "type" gives: 3
Level row2 "size" gives: 100
Level --- row1 "name" gives: bee
Level --- row1 "name" gives: wasp