Opdeling af afgrænsede værdier i en SQL-kolonne i flere rækker

Hvis du er på SQL Server 2016+

Du kan bruge den nye STRING_SPLIT funktion, som jeg har blogget om her, og Brent Ozar har blogget om her.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Hvis du stadig er på en version før SQL Server 2016

Opret en delt funktion. Dette er blot et af mange eksempler derude:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Jeg har diskuteret et par andre her, her, og en bedre tilgang end at splitte i første omgang her.

Nu kan du ekstrapolere ved at:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Jeg foreslår også, at du ikke sætter bindestreger i kolonnenavne. Det betyder, at du altid skal sætte dem i [square brackets] .