Hvordan får man fil fra BLOB i Oracle?

I denne øvelse lærer du, hvordan du får en fil fra BLOB-kolonnen i Oracle. For at give et eksempel har jeg oprettet en tabel EXT_FILES i Oracle, og følgende er tabellens struktur.

CREATE TABLE EXT_FILES
(
FILE_NAME VARCHAR2(1000 BYTE),
FILE_CONTENT BLOB
)
/

Indsæt dataene i ovenstående tabel. Hvis du ikke ved, hvordan du indsætter en fil i BLOB-kolonnen, så tjek følgende artikel Hvordan indsætter du en fil i Oracle Table BLOB-kolonnen?

Du skal have et Oracle-biblioteksobjekt oprettet i dit skema for at få filerne fra BLOB-kolonnen til disken. For at oprette en mappe i Oracle giv følgende kommando.

CREATE OR REPLACE DIRECTORY IMGDIR AS 'C:\TEMP\IMAGES';

Nedenstående er Oracle Stored Procedure-eksemplet, som henter posterne fra EXT_FILES-tabellen (indeholder BLOB-data) ved hjælp af en markør og derefter vil udpakke filerne én efter én til den angivne mappe.

Oracle Stored Procedure Eksempel for at hente filen fra BLOB Column i Oracle

CREATE OR REPLACE PROCEDURE get_files_from_blob
IS
l_file UTL_FILE.file_type;
l_buffer RAW (32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER := 1;
l_blob_len INTEGER;
l_blob BLOB;
l_filename ext_files.file_name%TYPE;
/* cursor to get the records from the table */
CURSOR c_files
IS
SELECT file_name, file_content FROM ext_files;
BEGIN
OPEN c_files;

LOOP

FETCH c_files
INTO l_filename, l_blob;

EXIT WHEN c_files%NOTFOUND;

l_blob_len := DBMS_LOB.getlength (l_blob);

/* Change the directory name (IMGDIR) to your Oracle directory object name*/
l_file :=
UTL_FILE.fopen ('IMGDIR',
l_filename,
'wb',
32767);
l_pos := 1;

WHILE l_pos < l_blob_len
LOOP
DBMS_LOB.read (l_blob,
l_amount,
l_pos,
l_buffer);
UTL_FILE.put_raw (l_file, l_buffer, TRUE);
l_pos := l_pos + l_amount;
END LOOP;

UTL_FILE.fclose (l_file);
END LOOP;

CLOSE c_files;
EXCEPTION
WHEN OTHERS
THEN
IF UTL_FILE.is_open (l_file)
THEN
UTL_FILE.fclose (l_file);
END IF;

RAISE;
END;

Test

BEGIN
get_files_from_blob;
END;
/

Output

PL/SQL procedure successfully completed.

Du kan nu kontrollere placeringen af ​​IMGDIR-biblioteksobjektet for de udpakkede filer.

Se også:

• Udtræk BLOB-data fra Oracle Table ved hjælp af Toad