Dvale kryptering af databasen fuldstændig gennemsigtig for applikationen

Hvis du afslutter arbejdet i applikationen, kan du bruge tilpassede typer i Hibernate, og det ville ikke tilføje så mange ændringer til din kode.

Her er en krypteret streng tilpasset type, som jeg har brugt:

import org.hibernate.usertype.UserType
import org.apache.log4j.Logger

import java.sql.PreparedStatement
import java.sql.ResultSet
import java.sql.SQLException
import java.sql.Types

class EncryptedString implements UserType {

  // prefix category name with 'org.hibernate.type' to make logging of all types easier
  private final Logger _log = Logger.getLogger('org.hibernate.type.com.yourcompany.EncryptedString')

  Object nullSafeGet(ResultSet rs, String[] names, Object owner) throws SQLException {
    String value = rs.getString(names[0])

    if (!value) {
      _log.trace "returning null as column: $names[0]"
      return null
    }

    _log.trace "returning '$value' as column: $names[0]"
    return CryptoUtils.decrypt(value)
  }

  void nullSafeSet(PreparedStatement st, Object value, int index) throws SQLException {
    if (value) {
      String encrypted = CryptoUtils.encrypt(value.toString())
      _log.trace "binding '$encrypted' to parameter: $index"
      st.setString index, encrypted
    }
    else {
      _log.trace "binding null to parameter: $index"
      st.setNull(index, Types.VARCHAR)
    }
  }

  Class<String> returnedClass() { String }

  int[] sqlTypes() { [Types.VARCHAR] as int[] }

  Object assemble(Serializable cached, Object owner) { cached.toString() }

  Object deepCopy(Object value) { value.toString() }

  Serializable disassemble(Object value) { value.toString() }

  boolean equals(Object x, Object y) { x == y }

  int hashCode(Object x) { x.hashCode() }

  boolean isMutable() { true }

  Object replace(Object original, Object target, Object owner) { original }
}

og baseret på dette skulle det være nemt at oprette lignende klasser for int, long, osv. For at bruge det, skal du tilføje typen til kortslutningen:

class MyDomainClass {

  String name
  String otherField

  static mapping = {
    name type: EncryptedString
    otherField type: EncryptedString
  }
}

Jeg har udeladt metoderne CryptoUtils.encrypt() og CryptoUtils.decrypt(), da det ikke er Grails-specifikt. Vi bruger AES, f.eks. "Cipher cipher =Cipher.getInstance('AES/CBC/PKCS5Padding')". Uanset hvad du ender med at bruge, så sørg for, at det er en 2-vejs krypto, dvs. brug ikke SHA-256.