Sådan tilføjer du primær nøglebegrænsning til identitetskolonner til alle tabellerne i SQL Server-databasen

Scenarie:

Du arbejder som SQL Server-udvikler. Du har dette krav, hvor du skal oprette primærnøglebegrænsning på alle identitetskolonner på alle tabellerne i SQL Server-databasen, hvis det ikke findes.
Primærnøglenavnet skal være Pk_SchemaName_TableName_ColumnName.

Løsning:

Først og fremmest er vi nødt til at få listen over tabeller, som har identitetskolonne, og der ikke er oprettet en Primary Key Constraint på dem. vi vil bruge systemtabeller og systemvisninger til at få alle tabeller med identitetskolonner, som ikke har primære nøglebegrænsninger.
Så skal vi bruge markøren med dynamisk SQL til at generere Alter-sætning til tabel for at tilføje Primary Key Constraint og udføre scriptet.

USE YourDatabaseName
GO

--Declare Variables
DECLARE @DatabaseName AS VARCHAR(128)
DECLARE @SchemaName AS VARCHAR(128)
DECLARE @TableName AS VARCHAR(128)
DECLARE @ColumnName AS VARCHAR(128)

DECLARE CUR CURSOR
FOR
--Get list of tables with Identity Column
--on which have no Primary Key
SELECT DB_Name() AS DatabaseName
    ,Schema_Name(Schema_id) AS TableSchema
    ,OBJECT_NAME(c.OBJECT_ID) AS TableName
    ,c.NAME AS ColumnName
FROM sys.columns c
INNER JOIN sys.tables t ON c.object_id = t.object_id
WHERE is_identity = 1
    AND type_desc = 'USER_TABLE'

EXCEPT

SELECT TC.Table_Catalog AS DatabaseName
    ,TC.Table_Schema AS TableSchema
    ,TC.Table_Name AS TableName
    ,CCU.Column_Name AS ColumnName
FROM information_Schema.Table_Constraints TC
INNER JOIN Information_Schema.constraint_column_usage CCU

ON TC.Constraint_Name = CCU.Constraint_Name
    AND TC.Table_Name = CCU.Table_Name
WHERE Constraint_Type = 'PRIMARY KEY'

OPEN Cur

FETCH NEXT
FROM Cur
INTO @DatabaseName
    ,@SchemaName
    ,@TableName
    ,@ColumnName

WHILE @@FETCH_STATUS = 0
BEGIN
    --Build dynamic sql for each database 
    DECLARE @SQL VARCHAR(MAX) = NULL

    SET @SQL = 'Alter Table [' + @SchemaName + '].[' + @TableName + ']' + CHAR(10)
    SET @SQL += 'Add Constraint [Pk_' + @SchemaName

+ '_' + @TableName

             + '_' + @ColumnName + '] '
    SET @SQL += 'Primary Key ([' + @ColumnName + '])'

    EXEC (@SQL)

    PRINT @SQL

    FETCH NEXT
    FROM Cur
    INTO @DatabaseName
        ,@SchemaName
        ,@TableName
        ,@ColumnName
END

CLOSE Cur

DEALLOCATE Cur

Hvis du bare vil generere alter-sætningerne for at tilføje Primary Key Constraint, kan du tilføje en kommentar til Exec(@SQL)-delen. Ovenstående script vil udskrive Alter-sætninger, og du kan køre på din bekvemmelighed.
Også hvis du ikke Jeg kan ikke lide at føje skemanavnet til Primary Key constraint, du kan fjerne @SchemaName.
Jeg udførte ovenstående forespørgsel, og det skabte Primary Key Constraint på identitetskolonner, hvor den manglede.

Ændre scripts genereret af script for at tilføje primær nøglebegrænsning til identitetskolonner

Jeg har bekræftet tabellerne og de primære nøglebegrænsninger blev oprettet.

Sådan opretter du primær nøglebegrænsning på identitetskolonner i SQL Server-databasen

Sådan tilføjer du primær nøglebegrænsning til identitetskolonner til alle tabellerne i SQL Server-databasen - SQL Server / TSQL Selvstudium Del 63

Scenarie:

Løsning: