Tabelfunktion med masseindsamling kaster ugyldig datatype

Du forsøger at bruge typer på pakkeniveau i almindelig SQL, hvilket ikke er tilladt. De erklærede typer i pakken er ikke synlige for eller gyldige uden for PL/SQL (eller endda i almindelige SQL-sætninger i PL/SQL). En beskåret version af det, du laver:

create or replace package types as
    type my_rec_type is record (dummy dual.dummy%type);
    type my_table_type is table of my_rec_type index by binary_integer;
end types;
/

create or replace package p42 as
    function get_table return types.my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return types.my_table_type is
        my_table types.my_table_type;
    begin
        select * bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

SQL Error: ORA-00902: invalid datatype

Selv inden for pakken, hvis du havde en procedure, der forsøgte at bruge tabelfunktionen, ville den fejle. Hvis du tilføjede:

    procedure test_proc is
    begin
        for r in (select * from table(get_table)) loop
            null;
        end loop;
    end test_proc;

... kompileringen af ​​pakketeksten ville mislykkes med ORA-22905: cannot access rows from a non-nested table item .

Du skal erklære typerne på skemaniveau, ikke i en pakke, så brug SQL create type kommando :

create type my_obj_type is object (dummy varchar2(1));
/

create type my_table_type is table of my_obj_type;
/

create or replace package p42 as
    function get_table return my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return my_table_type is
        my_table my_table_type;
    begin
        select my_obj_type(dummy) bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

DUMMY
-----
X