Giver Oracle muligheden for at returnere flere understrenge fra en streng/klob-række, der er blevet parset?

Noget som dette måske:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN sys.dbms_debug_vc2coll PIPELINED
IS  
  pos PLS_INTEGER;
  lastpos PLS_INTEGER;
  element varchar(2000);
BEGIN
   lastpos := 1;
   pos := instr(longline, ',');

   while pos > 0 loop
      element := substr(longline, lastpos, pos - lastpos);
      lastpos := pos + 1;
      pos := instr(longline, ',', lastpos);
      pipe row(element);
   end loop;

   if lastpos <= length(longline) then
      pipe row (substr(longline, lastpos));
   end if;

   RETURN;
END;  
/

Dette kan bruges sådan her:

SQL> select * from table(explode('1,2,3'));

COLUMN_VALUE
---------------------------------------------
1
2
3
SQL>

Hvis du ikke er på 11.x, skal du selv definere returtypen:

create type char_table as table of varchar(4000);

og ændre funktionserklæringen til:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN char_table pipelined
.....