Oracle SQL Insert Trigger to Hash Password virker ikke (Problem med CHAR)

[TL;DR] Brug STANDARD_HASH( RTRIM( :new.PASSWORD ), 'SHA256' ) som du vil generere adgangskoden på 'BruteForce' og ikke 'BruteForce ' (osv.) polstret med mellemrum til en længde på 64 tegn (hvilket er hvad der bruger CHAR(64) ville give dig).

Hvis du ikke ønsker at bruge et salt (som du burde bruge i denne dag og alder), skal du bare højretrimme adgangskoden for at slippe af med det bagende mellemrum, som CHAR datatypen har udfyldt strengen med:

CREATE OR REPLACE TRIGGER client_hash_trigger
BEFORE INSERT ON client
FOR EACH ROW
BEGIN
  SELECT STANDARD_HASH( RTRIM( :new.PASSWORD ), 'SHA256' )
  INTO   :new.PASSWORD
  FROM   DUAL;
END;
/

Så:

CREATE TABLE client (
    id            NUMBER(10,0)
                  GENERATED ALWAYS AS IDENTITY
                  CONSTRAINT client__id__pk PRIMARY KEY,
    password      CHAR(64)
                  NOT NULL
);

INSERT INTO client (id, password) VALUES (DEFAULT, 'BruteForce');

Vil udsende:

SELECT id, password FROM client;

Hashing og saltning

Tilpasset fra dette svar

Hvis du også vil følge bedste praksis, så bør du salte adgangskoden før hash:

CREATE TABLE client (
    id            NUMBER(10,0)
                  GENERATED ALWAYS AS IDENTITY
                  CONSTRAINT client__id__pk PRIMARY KEY,
    password      CHAR(64)
                  NOT NULL,
    password_salt VARCHAR2(61)
                  NOT NULL
);

Så er din trigger:

CREATE TRIGGER client_hash_trigger
BEFORE INSERT OR UPDATE ON client
FOR EACH ROW
BEGIN
  IF :new.PASSWORD = :old.PASSWORD THEN
    -- Assume things haven't changed (The chances of a hash collision are vanishingly small).
    -- Make sure the old salt is not replaced if the password hash hasn't changed.
    :new.PASSWORD_SALT := :old.PASSWORD_SALT;
  ELSE
    -- Regenerate a new salt and hash the password.
    :new.PASSWORD_SALT := DBMS_RANDOM.STRING( 'P', FLOOR( DBMS_RANDOM.VALUE( 40, 61 ) ) );
    SELECT STANDARD_HASH ( :new.PASSWORD_SALT || RTRIM( :new.PASSWORD ), 'SHA256' )
    INTO   :new.PASSWORD
    FROM   DUAL;
  END IF;
END;
/

Og så:

INSERT INTO client (id, password) VALUES (DEFAULT, 'BruteForce');

Kan output:

SELECT * FROM client;

db<>fiddle her