Hvordan gemmer man BLOB som fil i PL/SQL?

Her giver jeg et eksempel på at gemme BLOB-data som en fil i PL/SQL. BLOB-data kan du hente dem fra tabellen med BLOB-kolonnen, eller du kan hente dem fra en fil på disken.

PL/SQL-funktionseksempel for at gemme BLOB som en fil

Nedenstående procedure tager følgende tre argumenter:

1. Oracle Directory Objektnavn (som i_dir).
2. Gem som filnavn (som i_fil).
3. BLOB-data (som i_blob).

CREATE OR REPLACE PROCEDURE blob_to_file (i_dir    IN VARCHAR2,
                                          i_file   IN VARCHAR2,
                                          i_blob   IN BLOB)
AS
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
BEGIN
   l_blob_len := DBMS_LOB.getlength (i_blob);

   l_file :=
      UTL_FILE.fopen (i_dir,
                      i_file,
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP
      DBMS_LOB.read (i_blob,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (l_file)
      THEN
         UTL_FILE.fclose (l_file);
      END IF;

      RAISE;
END blob_to_file;

Test

Den følgende PL/SQL-blok kalder ovenstående procedure ved at sende Oracle-biblioteksobjektet, filnavnet og BLOB-dataene. Til BLOB-dataene bruger jeg funktionen GET_BLOB, som jeg har givet et eksempel på i mit tidligere blogindlæg:Hent BLOB fra en fil i PL/SQL. I nedenstående tilfælde vil den hente BLOB-dataene fra en fil myfile.jpg fra MY_DIR-placeringen og gemme den til filen abc.jpg i IMG_DIR-placeringen.

DECLARE
   f_blob   BLOB;
BEGIN
   /* check the above mentioned link for get_blob function example */
   f_blob := get_blob ('MY_DIR', 'myfile.jpg');
   /* now pass the blob to blob_to_file procedure to save it as a file */
   blob_to_file ('IMG_DIR', 'abc.jpg', f_blob);
END;

Nu kan du kontrollere placeringen af ​​IMG_DIR-biblioteket for filen oprettet via BLOB.

Se også:

• Hvordan opretter man et Oracle Directory-objekt?
• Lær, hvordan du udtrækker BLOB-data fra Oracle Table ved hjælp af Toad