Hvordan kontrollerer man, om filen er et billede, der bruger PL/SQL?

I dette blogindlæg deler jeg en funktion, som du kan tjekke om en fil er en billedfil eller ikke bruger PL/SQL. Programmet vil kontrollere filen ved at læse dens overskrift og ikke filtypenavnet. I øjeblikket kan funktionen identificere tre typer billeder, som er JPG, PNG og GIF.

PL/SQL-funktion til at kontrollere, om filen er en billedfil

Den følgende PL/SQL-funktion læser filoverskriften og returnerer derefter billedtypen i varchar2-datatypen. Funktionen get_image_type tager to argumenter, og de er som følger:

1. Oracle Directory Object (som i_dir) Lær hvordan du opretter Oracle Directory Object.
2. Filnavn (som i_file) fil bør eksistere i mappen.

CREATE OR REPLACE FUNCTION get_image_type (i_dir    IN VARCHAR2,
                                           i_file   IN VARCHAR2)
   RETURN VARCHAR2
AS
   l_bfile       BFILE;
   l_blob        BLOB;
   l_file_type   VARCHAR2 (50);
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   IF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 8, 1)) = '89504E470D0A1A0A'
   THEN
      l_file_type := 'PNG';
   ELSIF DBMS_LOB.SUBSTR (l_blob, 3, 1) = '474946'
   THEN
      l_file_type := 'GIF';
   ELSIF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 3, 1)) = 'FFD8FF'
   THEN
      l_file_type := 'JPG';
   ELSE
      l_file_type := 'The file is not an image.';
   END IF;

   RETURN l_file_type;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RETURN 'The file does not exists.';
END get_image_type;

Test

I nedenstående PL/SQL-program skal du ændre MY_FILES Oracle-biblioteksobjektet med dit biblioteksobjekt og ændre filnavnet med den fil, der er tilgængelig i MY_FILES biblioteksplacering.

SET SERVEROUTPUT ON;

DECLARE
   i_image_type   VARCHAR2 (50);
BEGIN
   i_image_type := get_image_type ('MY_FILES', 'oracle-logo-gif-to-use.gif');

   IF i_image_type IN ('JPG', 'GIF', 'PNG')
   THEN
      DBMS_OUTPUT.put_line ('The file is a valid ' || i_image_type || ' image.');
   ELSE
      DBMS_OUTPUT.put_line (i_image_type);
   END IF;
END;
/

Output

The file is a valid GIF image.
PL/SQL procedure successfully completed.

Se også:

• Hvordan indsætter man en fil i Oracle Table ved hjælp af PL/SQL?