Oracle PL/SQL:Eksporter data fra en tabel til CSV

Lær, hvordan du bruger UTL_FILE pakke til at eksportere data fra en tabel til CSV-filen i Oracle PL/SQL.

I Oracle, pakken UTL_FILE indeholder mange procedurer og funktioner til at skrive en tekstfil. Nedenfor er syntaksdetaljerne og de nødvendige trin til at skrive en fil:

Syntaks og trin til at skrive en fil ved hjælp af UTL_FILE

-- Declare a variable to store file type
n_file UTL_FILE.FILE_TYPE;
-- Open the file in Begin section, it will open the file and return the file handle into the variable n_file
n_file := UTL_FILE.FOPEN('DIR_OBJ', 'YourCSVFileName.csv', 'w', 4000);
-- Write a single or multiple lines
UTL_FILE.PUT_LINE(n_file, 'abc, xyz, xxx');
-- Close the file
UTL_FILE.FCLOSE(n_file);

Grundlæggende eksempel

Declare
   n_file Utl_File.File_Type;
Begin
   -- The directory object MY_DIR must be exist or create a new one
   n_file := Utl_File.Fopen('MY_DIR', 'myfile.csv', 'w', '4000');

   Utl_File.Put_Line(n_file, 'First line.');
   Utl_File.Put_Line(n_file, 'Second line.');
   Utl_File.Put_Line(n_file, 'Third line.');

   Utl_File.Fclose(n_file);
End;

Som jeg nævnte i ovenstående eksempel, mappeobjektet MY_DIR skal eksistere. Katalogobjektet i Oracle er en reference til den fysiske mappe på serveren. Følgende er et eksempel på oprettelse af et biblioteksobjekt i Oracle:

-- Windows example
CREATE OR REPLACE DIRECTORY CSVDIR AS 'd:\oracle\csvfiles';
-- Linux example
CREATE OR REPLACE DIRECTORY CSVDIR AS '/usr1/oracle/csvfiles';

For at lære mere om biblioteksobjektet i Oracle, tjek dette link.

Eksporter data fra en tabel til CSV i Oracle-eksempel

Det følgende er et eksempel på en lagret procedure i Oracle, som eksporterer data fra EMP-tabellen til en CSV-fil:

Create Or Replace Procedure exp_emp_data Is

    n_file     utl_file.file_type;
    v_string   Varchar2(4000);
   
  -- get the data using cursor 
  Cursor c_emp Is
    Select
        empno,
        ename,
        deptno,
        sal,
        comm
    From
        emp;

Begin
    n_file := utl_file.fopen('CSVDIR', 'empdata.csv', 'w', 4000);

-- if you do not want heading then remove below two lines
    v_string := 'Emp Code, Emp Name, Dept, Salary, Commission';
    utl_file.put_line(n_file, v_string);
    
    -- open the cursor and concatenate fields using comma
    For cur In c_emp Loop
        v_string := cur.empno
                    || ','
                    || cur.ename
                    || ','
                    || cur.deptno
                    || ','
                    || cur.sal
                    || ','
                    || cur.comm;
        
        -- write each row
        utl_file.put_line(n_file, v_string);
    End Loop;
    
    -- close the file
    utl_file.fclose(n_file);
Exception
    When Others Then
        -- on error, close the file if open
        If utl_file.is_open(n_file) Then
            utl_file.fclose(n_file);
        End If;
End;

Nu er din lagrede procedure blevet oprettet, kør den for at eksportere dataene:

Begin
    exp_emp_data;
End;

Relaterede selvstudier:

• Utility:Generer PL/SQL-procedure til eksport af data fra en tabel