Hvordan henter jeg værdier fra en indlejret Oracle-procedure?

Det ser ud til, at du ønsker at flette et ukendt antal SYS_REFCURSOR resultatsæt til ét stort. Hvis du kender strukturen af ​​markøren, der returneres fra spSelect_Inv_Search du kan gøre dette med en mellemliggende pipeline-funktion.

create package p as
    type tmp_rec_type is record (owner all_objects.owner%type,
        object_type all_objects.object_type%type,
        objects number);
    type tmp_rec_table is table of tmp_rec_type;

    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor);
    function func2 return tmp_rec_table pipelined;
    procedure proc3(p_cursor out sys_refcursor);
end;
/

Typerne kan defineres her, de behøver ikke at være på SQL-niveau, da du aldrig behøver at henvise til dem uden for pakken.

create package body p as
    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor) as
    begin
        open p_cursor for select owner, object_type, count(*)
            from all_objects
            where owner = p_owner
            group by owner, object_type;
    end;

    function func2 return tmp_rec_table pipelined as
        cursor c1 is select distinct owner
            from all_tables where owner in ('SYS','SYSTEM');
        tmp_cursor sys_refcursor;
        tmp_rec tmp_rec_type;
    begin
        for r1 in c1 loop
            proc1(r1.owner, tmp_cursor);
            loop
                fetch tmp_cursor into tmp_rec;
                exit when tmp_cursor%notfound;
                pipe row(tmp_rec);
            end loop;
        end loop;
    end;

    procedure proc3(p_cursor out sys_refcursor) as
    begin
        open p_cursor for select * from table(func2);
    end;
end p;
/

Så for at udføre, hvilket du kan gøre uden for pakken på trods af de typer, der bruges til mellemtrinnet, kan du gøre dette for at teste i SQL*Plus eller SQL Developer:

var rc refcursor;
exec p.proc3(:rc);
print rc;

For min database giver dette:

OWNER                          OBJECT_TYPE         OBJECTS                
------------------------------ ------------------- ---------------------- 
SYSTEM                         VIEW                1                      
SYSTEM                         TABLE               5                      
SYS                            VIEW                1056                   
SYS                            CONSUMER GROUP      2                      
SYS                            PROCEDURE           11                     
SYS                            FUNCTION            56                     
SYS                            SEQUENCE            1                      
SYS                            OPERATOR            6                      
SYS                            EVALUATION CONTEXT  1                      
SYS                            TABLE               13                     
SYS                            WINDOW GROUP        1                      
SYS                            PACKAGE             162                    
SYS                            WINDOW              2                      
SYS                            TYPE                529                    
SYS                            JOB CLASS           1                      
SYS                            SCHEDULE            1     

Dette er tydeligvis meget konstrueret, da du ville gøre dette som en enkelt forespørgsel, men jeg går ud fra, at din indre procedure skal gøre noget mere kompliceret.