Gå gennem løkken for at finde gentagne navne

Foretag ikke sløjfer i sløjfer i PL/SQL til dette - brug SQL for at give dig dataene klar til brug.

Først opretter vi din tabel med nogle testdata (jeg gætter på datatyper - du erstatter med din egen) :

create table product_master (
   product_no        varchar2(10)
 , product_holder    varchar2(10)
 , product_catalogue varchar2(10)
)
/

insert into product_master values ('1', 'SMITH', 'TEMP')
/
insert into product_master values ('2', 'SMITH', 'TEMP')
/
insert into product_master values ('3', 'HARRY', 'ARCH')
/
insert into product_master values ('4', 'TOM'  , 'DEPL')
/
commit
/

Hvad vi vil sende til mail_send procedure for hver product_holder er en samling (array), der indeholder product_no og product_catalogue . Så først en type, der indeholder disse to elementer:

create type t_prod_cat_no as object (
   product_no        varchar2(10)
 , product_catalogue varchar2(10)
)
/

Og så en indlejret tabeltype (samlingstype) af denne type:

create type t_prod_cat_no_table as
   table of t_prod_cat_no
/

Proceduren mail_send bør derefter acceptere product_holder og samlingstypen:

create or replace procedure mail_send (
   p_parameter        in varchar2
 , p_product_holder   in varchar2
 , p_product_cats_nos in t_prod_cat_no_table
)
is
begin
   dbms_output.put_line('-- BEGIN '||p_parameter||' --');
   dbms_output.put_line('Dear '||p_product_holder);
   dbms_output.put_line('Your products are:');
   for i in 1..p_product_cats_nos.count loop
      dbms_output.put_line(
         'Catalogue: '||p_product_cats_nos(i).product_catalogue||
         ' - No: '||p_product_cats_nos(i).product_no
      );
   end loop;
end mail_send;
/

(Jeg bruger bare dbms_output til at simulere opbygning af en mail.)

Så kan du i SQL lave en group by product_holder og lad SQL generere samlingen, der indeholder dataene:

begin
   for holder in (
      select pm.product_holder
           , cast(
                collect(
                   t_prod_cat_no(pm.product_no,pm.product_catalogue)
                   order by pm.product_catalogue
                          , pm.product_no
                ) as t_prod_cat_no_table
             ) product_cats_nos 
        from product_master pm
       group by pm.product_holder
       order by pm.product_holder
   ) loop
      mail_send(
         'PRODMASTER'
       , holder.product_holder
       , holder.product_cats_nos
      );
   end loop;
end;
/

Outputtet fra ovenstående blok vil være:

-- BEGIN PRODMASTER --
Dear HARRY
Your products are:
Catalogue: ARCH - No: 3
-- BEGIN PRODMASTER --
Dear SMITH
Your products are:
Catalogue: TEMP - No: 1
Catalogue: TEMP - No: 2
-- BEGIN PRODMASTER --
Dear TOM
Your products are:
Catalogue: DEPL - No: 4

Gør det i SQL med en GROUP BY giver dig alt i et enkelt opkald fra PL/SQL til SQL, hvilket er meget mere effektivt end det første opkald for at få det særskilte sæt product_holder , sløjfe over det, og derefter ét opkald pr. product_holder for at få produkterne til hver holder.

OPDATERING:

Tilføjet order by til collect funktion i ovenstående kode for at vise, at du har kontrol over rækkefølgen, som dataene udfyldes i samlingen.