Manipulering af samlinger

I det mindste mistede du en tabeldefinition i andet tilfælde. Denne erklæring:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

erklærer kun objekt (eller post) type, ikke en tabel.

Så du skal gøre det i 2 trin:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Derefter har du brug for nogle syntaksrettelser i scriptet:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

OPDATERING

Løsningen ovenfor er relativt langsom på grund af det store antal kontekstskift. Men sammenligning af komplekse objekttypeforekomster kan ikke udføres direkte i PL/SQL uden noget ekstra arbejde.
For at give Oracle mulighed for at vide, om objektforekomster er ens eller forskellige, skal vi definere tilknytnings- eller bestillingsmetode for objekttype . Begge typer metoder er ikke tilladt, så der er behov for at vælge den rigtige. MAP-metoder fungerer hurtigere, og der er ikke behov for at bestille i vores tilfælde, så gå efter det:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Implementering:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Derefter er det muligt at teste objekter for lighed i PL/SQL-kode som simpel varchar2 i første eksempel fra spørgsmål:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/