Sådan tjekker du versionen af ​​oracle provider til ole-db. OraOLEDB.Oracle udbyder

Du kan f.eks. bruge værktøjet RegDllView. Søg efter "OraOLEDB", resultatet kunne være dette:

En enklere tilgang ville være at navigere til din ORACE_HOME\bin bibliotek og find filen OraOLEDB??.dll . Tjek version med højre museklik -> Egenskaber -> Detaljer.

Men du får bare versionen af ​​filen, det betyder ikke nødvendigvis, at denne DLL også er registreret og klar til brug.

Eller brug dette VBScript:

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

OLE DB-udbyder kan eksistere i 32-bit eller/og i 64-bit, så du kan udføre scriptet to gange:

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs